;trhncagp2h3d2
;avance-version (12/01/11)
;TROSY-HNCA
;3D sequence with
;   inverse correlation for triple resonance
;      via TROSY and inept transfer steps
;
;      F1(H) -> F3(N) -> F2(Ca,t1) -> F3(N,t2) -> F1(H,t3)
;
;on/off resonance Ca and C=O pulses using shaped pulse
;phase sensitive (t1)
;phase sensitive using Echo/Antiecho (t2)
;using constant time in t2
;with H-2 decoupling - requires lockswitch unit or BSMS 2H-TX board
;with H-1 180degree pulses in t1
;
; CB and/or CO decoupling during Ca evolution with Optimal Control Pulses
;
;(use parameterset TRHNCAGP2H3D2)
;
;(M. Salzmann, K. Pervushin, G. Wider, H. Senn & K. Wuethrich, Proc.
;   Natl. Acad. Sci. USA 95, 13585-13590 (1998))
;A. Eletsky, A. Kienhoefer & K. Pervushin,
;   J. Biomol. NMR 20, 188-180 (2001)
;
;P. Coote, S. Robson, A. Dubey, A. Boeszoermenyi, G. Wagner & H. Arthanari, Nat. Comm (under review 2018)
; 
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


prosol relations=<triple>


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"p22=p21*2"
"d11=30m"
"d12=20u"

"d23=12m"
"d26=2.3m"


"d0=3u"
"d10=3u"
"d30=d23-p11-8u-p1"

"in0=inf1/4"
"in10=inf2/2"

"in30=in10"


"d41=p15*cnst13"




"DELTA=d0*4+larger(p14,p22)-p14+p2*2-4u"
"DELTA1=d26-p11-p16-d16-8u"
"DELTA2=d23-d10-p14-p21*4/3.1416"
"DELTA3=d26-p16-d16"
"DELTA4=d0*4+p2*2"

"l0=1"

"d39=d41/4"

"spoff2=0"
"spoff3=0"
"spoff5=bf2*(cnst21/1000000)-o2"
"spoff8=0"


aqseq 321


1 d11 ze
  d11 LOCKDEC_ON
  50u LOCKH_ON
  d11 H2_PULSE
  d11 pl17:f4

2 d11
3 d11 H2_LOCK
  20u 
  "d15=(4*d0-2*p2-d41)/4"
  9m LOCKH_OFF
  d1 pl1:f1
  50u UNBLKGRAD
  d12 H2_PULSE

  p1 ph1
  4u pl0:f1
  (p11:sp1 ph3:r):f1
  4u
  p16:gp1
  d16 pl1:f1
  DELTA1
  (center (p2 ph2) (p22 ph1):f3 )
  DELTA1
  p16:gp1
  d16 pl0:f1
  (p11:sp1 ph4:r):f1
  4u
  4u pl1:f1
  (p1 ph4):f1 

  (p21 ph1):f3
  d23
  (center (p14:sp3 ph1):f2 (p22 ph1):f3 )
  d23
  (p21 ph2):f3

  20u cpd4:f4

  if "d15 < 0"
{
  (p13:sp2 ph5):f2
  d0
  (p2 ph1):f1
  d0
  (center (p14:sp5 ph1):f2 (p22 ph1):f3 )
  d0
  (p2 ph1):f1
  d0
  (p14:sp3 ph2):f2 
  DELTA
  (p14:sp5 ph1):f2
 4u
  (p13:sp8 ph1):f2
}
else
{
  (p13:sp2 ph5):f2
  d15
  (p2 ph1):f1
  d15
  (center (p15:sp10 ph9):f2 (p22 ph1):f3 )
  d15
  (p2 ph1):f1
  d15
  (p13:sp8 ph1):f2
}



  4u do:f4

  if "l0 %2 == 1"
     {
     (p21 ph6):f3
     }
  else
     {
     (p21 ph7):f3
     }

  d10
  (p14:sp5 ph1):f2
  DELTA2
  (center (p14:sp3 ph1):f2 (p22 ph1):f3 )
  d30 pl0:f1
  (p11:sp1 ph1:r):f1
  4u
  4u pl1:f1

  (p1 ph8)
  p16:gp2
  d16
  DELTA3
  (center (p2 ph1) (p22 ph1):f3 )
  DELTA3
  p16:gp2
  d16
  (center (p1 ph1) (p21 ph8):f3 )
  p16:gp3
  d16
  DELTA1 pl0:f1
  (p11:sp1 ph3:r):f1
  4u
  4u pl1:f1
  (center (p2 ph1) (p22 ph1):f3 )
  4u pl0:f1
  (p11:sp1 ph3:r):f1
  DELTA1
  p16:gp3
  d16 pl1:f1
  4u BLKGRAMP
  (p21 ph1):f3
  go=2 ph31
  d11 mc #0 to 2 
     F1PH(calph(ph5, +90), caldel(d0, +in0)) 
     F2EA(calph(ph8, +180) & calclc(l0, 1), caldel(d10, +in10) & caldel(d30, -in30))

  d11 H2_LOCK
  d11 LOCKH_OFF
  d11 LOCKDEC_OFF

exit


ph1=0
ph2=1 
ph3=2
ph4=3
ph5=0 0 0 0 2 2 2 2
ph6=1 3 0 2
ph7=1 3 2 0
ph8=3
ph9=0 3 1 2 1 0 3 2 
ph31=1 3 2 0 3 1 0 2


;pl0 : 0W
;pl1 : f1 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl17: f4 channel - power level for CPD/BB decoupling
;sp1: f1 channel - shaped pulse  90 degree  (H2O on resonance)
;sp2: f2 channel - shaped pulse  90 degree  (Ca on resonance)
;sp3: f2 channel - shaped pulse 180 degree  (Ca on resonance)
;sp5: f2 channel - shaped pulse 180 degree  (C=O off resonance)
;sp8: f2 channel - shaped pulse  90 degree  (Ca on resonance)
;                  for time reversed pulse
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p11: f1 channel -  90 degree shaped pulse             [1 msec]
;p13: f2 channel -  90 degree shaped pulse
;p14: f2 channel - 180 degree shaped pulse
;p15: length of decoupling pulse during Ca evolution
;p16: homospoil/gradient pulse                         [1 msec]
;p21: f3 channel -  90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;d0 : incremented delay (F1 in 3D)                     [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d10: incremented delay (F2 in 3D)                     [3 usec]
;d11: delay for disk I/O                               [30 msec]
;d12: delay for power switching                        [20 usec]
;d16: delay for homospoil/gradient recovery
;d23: 1/(4J(NCa)                                       [12 msec]
;d26: 1/(4J'(NH)                                       [2.3 msec]
;d30: decremented delay (F2 in 3D) = d23-p11-8u-p1
;cnst21: CO chemical shift (offset, in ppm)
;cnst22: Calpha chemical shift (offset, in ppm)
;cnst13: Corr factor GC=0.90 BC1=0.91 BC2=0.91 BC3=0.91
;o2p: Calpha chemical shift (cnst22)
;inf1: 1/SW(Ca) = 2 * DW(Ca)
;inf2: 1/SW(N) = 2 * DW(N)
;in0: 1/(4 * SW(Ca)) =  (1/2) DW(Ca)
;nd0: 4
;in10: 1/(2 * SW(N)) = DW(N)
;nd10: 2
;in30: = in10
;ns: 8 * n
;ds: >= 16
;td1: number of experiments in F1
;td2: number of experiments in F2       td2 max = 2 * d30 / in30
;FnMODE: States-TPPI (or TPPI) in F1
;FnMODE: echo-antiecho in F2
;cpd4: decoupling according to sequence defined by cpdprg4
;pcpd4: f4 channel - 90 degree pulse for decoupling sequence


;use gradient ratio:    gp 1 : gp 2 : gp 3
;                         30 :   18 :   44

;for z-only gradients:
;gpz1: 30%
;gpz2: 18%
;gpz3: 44%

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100



;$Id: trhncagp2h3d2,v 1.20.6.1 2012/01/31 17:56:39 ber Exp $